On the elliptic curve $X^3 + 6\cdot 163^2 X - 7\cdot 163^3 = Y^2$ and others

Question

I. Ellipse

Given the general equation,

$$a^3 + b^3 + c^3 = (c + m)^3$$

Let,

\begin{align} c &= (n + 1)(a - m) + n b\\ a &= p + q + m + 4 m n + 3 m n^2\\ b &= p - q + 2 m n + 3 m n^2 \end{align}

and after removing a trivial factor, it becomes the simple ellipse centered at the origin,

$$p^2 + 3 q^2 = d$$

where $d = 3m^2 n(n+1) (3 n^2 + 3n + 1).$ For example, the ellipse $p^2+3q^2-7=0$.

Choose some desired $d$ with integer $(p,q)$. Thus we need to solve for $m$,

$$m = d\,\sqrt{\frac1{3d n(n+1) (3 n^2 + 3n + 1)}}$$

and find rational $n$ such that $m$ is also rational. Assume prime $d=1\,(\text{mod}\,6)$, or Euler's Theorem, say $d=p^2+3q^2=7$ so $(p,q) = (2,1)$. Then one solution is $n = 1/3,\, m = 3/2$. Substituting $(p,q,m,n)$ into the expressions for $(a,b,c)$, we find,

$$\left(\frac{42}{6}\right)^3 + \left(\frac{15}{6}\right)^3 + \left(\frac{49}{6}\right)^3=\left(\frac{49}{6}+\frac{3}{2}\right)^3$$

---

II. Elliptic curve

Here's the difficult part: Characterize which prime $d=p^2+3q^2$ such that the quartic in $n$ to be made a square is solvable,

$$3d n(n+1) (3 n^2 + 3n + 1) = w^2$$

with $w\neq 0$. After some correspondence with S. Tomita, we find this is birationally equivalent to a cubic in $X$ to be made a square,

$$X^3 + 6d^2 X - 7d^3 = Y^2$$

or an elliptic curve. The primes of form $d=1\,(\text{mod}\,6) = p^2+3q^2$ are given by A002476. From that, I tested 150 primes with $d<2024$ using the online Magma calculator and found a LOT had rank $r > 0$ including $d = 163$. There were only 26 with rank $r=0$, namely,

$$73, 97, 193, 241, 337, 409, 457, 601, 673, 769, 937, 1009, 1033, 1129, 1153, \ 1201, 1249, 1297, 1321, 1489, 1609, 1753, 1777, 1801, 1873, 2017$$

so cannot be used for a non-trivial solution to $a^3 + b^3 + c^3 = (c + m)^3$. It can be observed they are a subset of A107008, the primes of form $u^2+72v^2.$

Update: Based on the Magma code in the answer below, the observation is apparently true for $d<40000$.

---

III. Question

Conjecture 1: Given the elliptic curve $X^3 + 6d^2 X - 7d^3 = Y^2$ with prime $d = p^2+3q^2$, then a necessary (but not sufficient) condition that it has rank $r=0$ is it is a subset of $d = u^2+72v^2$. (Only a subset since $\color{red}{313} =u^2+72v^2$ has rank $r = 2$.)

Conjecture 2: For those special $d = u^2+72v^2$ with rank $r=2$, then a necessary (but not sufficient) condition is it is a subset of $d = x^2+144y^2$. (Only a subset since $193=x^2+144y^2$ has rank $r = 0$.) For $d < 10009$, there are only 22,

$$\color{red}{313}, 433, 577, 1657, 1993, 2137, 3529, 3697, 4057, 4129, 4297, 4513, 4801, 6529, 6553, 7057, 8089, 8209, 8641, 9241, 9337, 9601$$

all of which have form $x^2+144y^2.$ If conjectures are not true, then what are the first counter-examples?

Note: Can someone test $d=1471$? Magma says it has rank $r=1$, but seems unable to give a generator.

Answer 1

The last question I answered in my comments, but I may as well give more details here. It is a usual thing that it is hard to find points when you have rank. Since the curve in question (where $d = 1471$) has rank $1$ one could use the Heegner point machinery (HeegnerPoint in Magma).

Alternatively (and as we do in practice in cases with higher rank) we can do a higher descent (higher descent -> point has smaller height -> easier to find). In this case, we have a $2$-torsion point, so $2$, $4$, and $8$-descent will be easier than the generic case.

d := 1471;
E := EllipticCurve([6*d^2, -7*d^3]);
C,_ := TwoDescent(E : RemoveTorsion:=true);
assert #C eq 1; 
C := C[1]; //2-covering of E which we conjecture has a point
D := FourDescent(C : RemoveTorsion:=true);
D := D[1];
E_prime, psi := AssociatedEllipticCurve(D);
assert E_prime eq E; //could in principle be a different model
eight_covs, phis := EightDescent(D);
pts := [];
for i in [1..#eight_covs] do
    cov := eight_covs[i]; phi := phis[i];
    new := PointSearch(cov, 1000);
    pts := pts cat [psi(phi(P)) : P in new];
end for;
gens := Saturation(pts);
Sprintf("Generators are:\n  T = %o \n  P = %o", gens[1], gens[2]);

---

Edit: Some more sophisticated searching code for the first conjecture.

bound := 200;
dd := {p^2 + 3*q^2 : p,q in [1..bound] | IsPrime(p^2 + 3*q^2)};
dd := [d : d in dd];
Sort(~dd);
sub_seq := {p^2 + 72q^2 : p,q in [1..4bound]};
rk_0 := [];
for d in dd do
    E := EllipticCurve([6d^2, -7d^3]);
    covs := TwoDescent(E : RemoveTorsion:=true);
    pairs := [<C,D,CasselsTatePairing(C,D)> : C,D in covs];
    to_remove := [];
    for p in [x : x in pairs | x[3] eq 1] do
        Append(~to_remove, p[1]);
        Append(~to_remove, p[2]);
    end for;
    filter := [c : c in covs | not c in to_remove];
    if #filter eq 0 then
        Append(~rk_0, <d, d in sub_seq>);
    end if;
end for;
[x : x in rk_0 | x[2] eq false];

And some better code for the second one

dd := {p^2 + 72*q^2 : p,q in [1..80] | IsPrime(p^2 + 72*q^2)};
dd := [d : d in dd];
Sort(~dd);
rk_non_0 := [];
for d in dd do
    E := EllipticCurve([6d^2, -7d^3]);
    covs := TwoDescent(E : RemoveTorsion:=true);
    if #covs ne 0 then
        pairs := [<C,D,CasselsTatePairing(C,D)> : C,D in covs];
        to_remove := [];
        for p in [x : x in pairs | x[3] eq 1] do
            Append(~to_remove, p[1]);
            Append(~to_remove, p[2]);
        end for;
        filter := [c : c in covs | not c in to_remove];
        if #filter ne 0 then
            _,rk_conj := IsPower(#filter + 1, 2);
            Append(~rk_non_0, <d, rk_conj>);
        end if;
    end if;
end for;
rk_non_0;
```