Integral involving a stretched exponential and a rational function

Question

This is a follow-up to this Integral involving a Gaussian and a rational function. question.

In Evaluating $\int_{\mathbb{R}}\frac{\exp(-x^2)}{1+x^2}\,\mathrm{d}x$ there are two methods for solving an integral from a product of an exponential function and a rational function. The first method is based on differentiating with respect to a parameter and solving an ODE whereas the second method is based on Fourier transforms (Parseval's identity). Now using the first method we obtained the following results.

Let $a \ge0$ and $b \ge 0$ be real numbers and $n \ge 1$ be an integer. Define: \begin{eqnarray} {\mathcal I}^{(4)}_{4 n}(a,b):= \int\limits_{-\infty}^\infty \frac{e^{-b x^4}}{a^{4 n} + x^{4 n}} dx \end{eqnarray} Clearly the quantity above satisfies the following ODE: \begin{equation} \left[(-1)^n \partial_b^n + a^{4 n}\right] {\mathcal I}^{(4)}_{4 n}(a,b) = \frac{2}{b^{1/4}} \Gamma(5/4) \quad (i) \end{equation} subject to \begin{eqnarray} \left.(-1)^j \partial_b^j {\mathcal I}^{(4)}_{4 n}(a,b)\right|_{b=0} = \frac{\pi}{2 n a^{4n-4j-1}} Csc[\frac{\pi(4j+1)}{4 n}] \quad (ii) \end{eqnarray} for $j=0,\cdots,n-1$.

Solving the ODE $(i)$ with initial conditions $(ii)$ by means of the Green's function method leads to the following solutions.

For $n=2$ we have: \begin{eqnarray} {\mathcal I}^{(4)}_{8}(a,b)&=& C_1 \sin(a^4 b) + C_2 \cos(a^4 b) - \frac{1}{a^4} \int\limits_0^b \left| \begin{array}{rr} \sin(a^4 \xi) & \cos(a^4 \xi)\\ \sin(a^4 b) & \cos(a^4 b) \end{array} \right| \frac{2}{\xi^{1/4}} \Gamma(5/4) d\xi \end{eqnarray} where \begin{eqnarray} C_1&:=&-\frac{\pi }{a^7 \left(\csc \left(\frac{\pi }{8}\right)+\sec \left(\frac{\pi }{8}\right)\right)}\\ C_2&:=&\frac{\pi \csc \left(\frac{\pi }{8}\right)}{4 a^7} \end{eqnarray}

{a, b} = RandomReal[{0, 1}, 2, WorkingPrecision -> 50];
NIntegrate[Exp[-b x^4]/(a^(8) + x^(8)), {x, -Infinity, Infinity}, 
 WorkingPrecision -> 30]
{C1, C2} = {-(\[Pi]/(
    a^7 (Csc[\[Pi]/8] + Sec[\[Pi]/8]))), (\[Pi] Csc[\[Pi]/8])/(4 a^7)};
 C1 Sin[a^4 b] + C2 Cos[a^4 b] - 
 1/a^4 NIntegrate[(Sin[a^4 xi] Cos[a^4 b] - Cos[a^4 xi] Sin[a^4 b]) 2/
     xi^(1/4) Gamma[5/4], {xi, 0, b}, WorkingPrecision -> 30]

Likewise for $n=3$ we have: \begin{eqnarray} {\mathcal I}^{(4)}_{12}(a,b)&=& C_0 e^{a^4 b} + C_+ e^{-(-1)^{1/3} a^4 b} + C_- e^{-(-1)^{-1/3} a^4 b} -\frac{1}{3 \imath \sqrt{3} a^{12}} \int\limits_0^b \left| \begin{array}{rrr} e^{a^4 \xi} & e^{-(-1)^{1/3} a^4 \xi} & e^{-(-1)^{-1/3} a^4 \xi} \\ a^4 e^{a^4 \xi} & -(-1)^{1/3} a^4 e^{-(-1)^{1/3} a^4 \xi} & -(-1)^{-1/3} a^4 e^{-(-1)^{-1/3} a^4 \xi} \\ e^{a^4 b} & e^{-(-1)^{1/3} a^4 b} & e^{-(-1)^{-1/3} a^4 b}\end{array} \right| \frac{2}{\xi^{1/4}} \Gamma(5/4) d\xi \end{eqnarray} where: \begin{eqnarray} C_0 &:=& \frac{\pi }{3 \sqrt{2} a^{11}}\\ C_+&:=&\frac{\pi }{\sqrt{6} \left(1+\sqrt[3]{-1}\right) a^{11}} \\ C_-&:=& \frac{\sqrt[6]{-1} \pi }{3 \sqrt{2} a^{11}} \end{eqnarray}

{a, b} = RandomReal[{0, 1}, 2, WorkingPrecision -> 50];
NIntegrate[Exp[-b x^4]/(a^(12) + x^(12)), {x, -Infinity, Infinity}, 
 WorkingPrecision -> 30]
W = 3 I Sqrt[3] a^12;
{C0, Cp, Cm} = {\[Pi]/(3 Sqrt[2] a^11), \[Pi]/(
   Sqrt[6] (1 + (-1)^(1/3)) a^11), ((-1)^(1/6) \[Pi])/(
   3 Sqrt[2] a^11)};
C0 E^(a^4 b) + Cp E^(-(-1)^(1/3) a^4 b) + Cm E^(-(-1)^(-1/3) a^4 b) - 
 1/W NIntegrate[
   Det[{{E^(a^4 xi), E^(-(-1)^(1/3) a^4 xi), 
       E^(-(-1)^(-1/3) a^4 xi)}, {a^4 E^(
        a^4 xi), -(-1)^(1/3) a^4 E^(-(-1)^(1/3) a^4 xi), (-1)^(2/3)
         a^4 E^((-1)^(2/3) a^4 xi)}, {E^(a^4 b), 
       E^(-(-1)^(1/3) a^4 b), E^(-(-1)^(-1/3) a^4 b)}}] 2/
     xi^(1/4) Gamma[5/4], {xi, 0, b}, WorkingPrecision -> 30]

In general we have: \begin{eqnarray} &&{\mathcal I}^{(4)}_{4 n}(a,b) =\\ && \frac{1}{n^2} \frac{\pi}{\sqrt{2}} \frac{(-1)^{1/n} b^{3/4}}{a^{4n-4}} \sum\limits_{p=0}^{n-1} \theta_n^p e^{-(-1)^{1/n} a^4 \theta_n^p b} \left(\frac{((-1)^{(n+1)/n})^{-3/4}}{ \theta_n^{3p/4} a^3 b^{3/4}} - \frac{E_{1/4}[-(-1)^{1/n} a^4 \theta_n^p b]}{\Gamma[3/4]} \right)+\\ &&\frac{\pi}{2 n^2 a^{4 n-1}} \sum\limits_{p=0}^{n-1} {\mathfrak C}^{(p)}_n e^{-b a^4 (-1)^{1/n} \theta_n^p} \end{eqnarray} where \begin{equation} {\mathfrak C}^{(p)}_n:= \sum\limits_{j=0}^{n-1} \frac{e^{-\imath \frac{\pi}{n} j (2p+1)}}{\sin(\pi \frac{4j+1}{4 n})} \end{equation} and $\theta_n := \exp(\imath 2 \pi/n)$ and $E_n[z]:= \int\limits_1^\infty \exp(-z t)/t^n dt$ is the exponential integral function .

Clear[th]; n =.; M = 6;
th[n_] := Exp[2 Pi I/n];
{a, b} = RandomReal[{0, 1}, 2, WorkingPrecision -> 50];
l1 = Table[
   NIntegrate[
    Exp[-b x^4]/(a^(4 n) + x^(4 n)), {x, -Infinity, Infinity}, 
    WorkingPrecision -> 30], {n, 1, M}];
l2 = Table[
   1/n^2 Pi/Sqrt[2] ((-1)^(1/n) b^(3/4))/a^(4 n - 4)
      Sum[th[n]^
       p Exp[-(-1)^(1/n) a^4 th[n]^p b] (((-1)^((n + 1)/(n)))^(-3/4)/(
          th[n]^(3 p/4) a^3 b^(3/4)) - 
         ExpIntegralE[1/4, -(-1)^(1/n) a^4 th[n]^p b]/Gamma[3/4]), {p,
        0, n - 1}] + 
    Pi/(2 n^2 a^(4 n - 1))
      Sum[Sum[  
        Csc[Pi (4 j + 1)/(4 n)] Exp[-((I Pi )/n) j (2 p + 1) ], {j, 0,
          n - 1}] Exp[-b a^4 (-1)^(1/n) th[n]^p], {p, 0, n - 1}], {n, 
    1, M}];
{l1, Re[N[l2, 30]]} // MatrixForm

My question would be can we derive those results in a different way, for example using the Parseval's identity? Another question is how about the case when the exponents in the denominator of the integrand are not an integer multiple of four, how do we proceed in that case?

Answer 1

In here we calculate the quantity ${\mathcal I}^{(2m)}_{2 n}(a,b)$ in the case when $m\ge 1$ and $n=m+1$. Note that in this case the differentiation with respect to a parameter method used in the question above does not work unless we resort to solving in-homogeneous ODEs with fractional derivatives, something that is beyond reach for me at the time being.

Let us compute the Laplace transform of the quantity in question with respect to the parameter $b$. We have: \begin{eqnarray} \tilde{y}(s):= {\mathcal L}_b\left[ {\mathcal I}^{(2m)}_{2 n}(a,b) \right](s) = \int\limits_{\mathbb R} \frac{1}{x^{2 m}+s}\cdot \frac{1}{x^{2 n}+a^{2 n}} dx \end{eqnarray} In order to compute the integral on the right hand side above we decompose the integrand into partial fractions and then use Cauchy theorem to do the integrals. We have: \begin{equation} \frac{1}{x^{2 m}+s}\cdot \frac{1}{x^{2 n}+a^{2 n}} = \sum\limits_{j=0}^{m-1} {\mathcal A}_j(s) \left(\frac{x^{2 j}}{x^{2m}+s}\right) + \sum\limits_{j=0}^{n-1} {\mathcal B}_j(s) \left(\frac{x^{2 j}}{x^{2 n}+a^{2 n}}\right) \end{equation} where \begin{eqnarray} {\mathcal B}_j(s) =\left\{ \begin{array}{rr} \frac{s^{n-1}}{s^n + a^{2 n(n-1)}} & \mbox{if $\quad j=0$}\\ -a^{2 n(n-1-j)}\frac{s^{j-1}}{s^n + a^{2 n(n-1)}} & \mbox{if $\quad j=1,\cdots,n-1$} \end{array} \right. \end{eqnarray} and ${\mathcal A}_j(s) = - {\mathcal B}_{j+1}(s)$ for $j=0,\cdots,n-2$. Now, using Cauchy integral theorem we easily carry out the integration over $x$ . We have: \begin{equation} \int\limits_{\mathbb R} \frac{x^{2 j}}{x^{2 n}+a^{2 n}} dx = \frac{\pi}{n} \frac{1}{a^{2n-2j-1}}\cdot \frac{1}{\sin(\frac{\pi}{n}(j+\frac{1}{2}))} \end{equation} for $j=0,\cdots,n-1$.

therefore the Laplace transform reads: \begin{eqnarray} {\tilde y}(s)=\frac{\pi}{m} \sum\limits_{j=0}^{m-1} \frac{a^{2n(n-2-j)}}{\sin(\frac{\pi}{m}(j+\frac{1}{2}))} \cdot \frac{s^j}{s^n + a^{2 n(n-1)}} \frac{1}{s^{\frac{2m-2j-1}{2 m}}} - \frac{\pi}{n} \sum\limits_{j=0}^{n-1} \frac{a^{3-2j(n-1)+2n(n-3)}}{\sin(\frac{\pi}{m}(j+\frac{3}{2}))} \cdot \frac{s^j}{s^n + a^{2 n(n-1)}} \end{eqnarray}

Now in order to compute the inverse Laplace transform we decompose the rational functions in $s$ into partial fractions: \begin{equation} \frac{s^j}{s^n + a^{2 n(n-1)}} = \frac{1}{n a^{2(n-1)(n-1-j)}} \sum\limits_{p=0}^{n-1} \frac{\left(e^{\frac{2 i \pi p}{n}+\frac{i \pi }{n}}\right)^j}{s-a^{2 (n-1)} e^{\frac{2 i \pi p}{n}+\frac{i \pi }{n}}} \cdot e^{-\frac{\imath \pi}{n} (n-1-2 p)} \end{equation} for $j=0,\cdots,n-1$.

Then we invert the Laplace transforms and we get: \begin{eqnarray} &&{\mathcal I}^{(2m)}_{2 n}(a,b) = \\ &&\!\!\!\!\!\!\!\!\!\!\!\!\!\!\!\!\!\!\frac{\pi a^{1-2 n}}{m n} \cdot \sum\limits_{p=0}^{n-1}\sum\limits_{j=0}^{m-1} \frac{e^{\frac{i \pi (2 j p+j-n)}{n}}}{\sin\left( \frac{\pi}{m}(j+\frac{1}{2})\right)} \left(e^{\frac{i (2 \pi p+\pi )}{n}}\right)^{\frac{2 j+1}{2 m}} e^{b a^{2 n-2} e^{\frac{2 i \pi p}{n}+\frac{i \pi }{n}}}\cdot \frac{\Gamma \left(\frac{-2 j+2 m-1}{2 m}\right)-\Gamma \left(\frac{-2 j+2 m-1}{2 m},a^{2 n-2} b e^{\frac{2 i \pi p}{n}+\frac{i \pi }{n}}\right)}{\Gamma \left(\frac{-2 j+2 m-1}{2 m}\right)} + \\ &&-\frac{\pi a^{1-2 n}}{n^2}\sum\limits_{p=0}^{n-1} \sum\limits_{j=0}^{n-1} \frac{e^{\frac{i \pi (2 j p+j-n+2 p+1)}{n}} }{\sin \left(\frac{\pi \left(j+\frac{3}{2}\right)}{n}\right)} \cdot e^{b a^{2 n-2} e^{\frac{2 i \pi p}{n}+\frac{i \pi }{n}}} \end{eqnarray}

m = RandomInteger[{1, 20}];
n = m + 1;
{a, b} = RandomReal[{0, 1}, 2, WorkingPrecision -> 50];
NIntegrate[Exp[-b x^(2 m)]/(
 x^(2 n) + a^(2 n)), {x, -Infinity, Infinity}, WorkingPrecision -> 40]
Sum[Pi/m a^(1 - 2 n)/Sin[Pi/m (j + 1/2)] (
   E^((I (j - n + 2 j p) \[Pi])/n) (E^((I (\[Pi] + 2 p \[Pi]))/n))^((
    1 + 2 j)/(2 m)))/n  E^(
   a^(2 n - 2) E^((I Pi)/n) E^((I 2 Pi)/n p)
     b)    (Gamma[(2 m - 2 j - 1)/(2 m)] - 
     Gamma[(2 m - 2 j - 1)/(2 m), 
      a^(2 n - 2) E^((I Pi)/n) E^((I 2 Pi)/n p) b])/
   Gamma[(2 m - 2 j - 1)/(2 m)] , {p, 0, n - 1} , {j, 0, m - 1}] - 
 Sum[ (Pi a^(1 - 2 n))/(n n) E^((I (1 + j - n + 2 p + 2 j p) \[Pi])/
   n)/Sin[Pi/n (j + 3/2)] E^(
   a^(2 n - 2) E^((I Pi)/n) E^((I 2 Pi)/n p) b), {p, 0, n - 1}, {j, 0,
    n - 1}]