Moving position of variable in a let clause

Question

I have the following code and wonder whether I can define the variable brace-stxcode in the let* part rather than I currently do (make a new let).

  (let* ( (last-ppss-pos (point))
          (ppss (syntax-ppss)) )
(while (> end (progn (skip-syntax-forward "^()" end)
                     (point) ))

  (let* ( (brace-pos (point))
          (brace-stx (syntax-after brace-pos)) )

    (setq ppss
          (parse-partial-sexp last-ppss-pos brace-pos nil nil ppss))
    (setq last-ppss-pos brace-pos)

    (forward-char)

    (let ( (brace-stxcode (car brace-stx)) )  ; <= from here to let*

      (cond
       ((conshine-ignore brace-pos ppss brace-stxcode)
           nil)

       ((= 4 (logand #xFFFF brace-stxcode))
           (conshine-colourise brace-pos (1+ (nth 0 ppss)) t))

       (t
           (let ( (matches-p
                   (eq (cdr brace-stx) (char-after (nth 1 ppss)))) )
             (conshine-colourise brace-pos (nth 0 ppss) matches-p)) ))) )))

Answer 1

Yes, why not?

(let* ((last-ppss-pos (point))
       (ppss (syntax-ppss)))
  (while (> end (progn (skip-syntax-forward "^()" end) (point)))
    (let* ((brace-pos     (point))
           (brace-stx     (syntax-after brace-pos))
           (brace-stxcode (car brace-stx)))
      (setq ppss (parse-partial-sexp last-ppss-pos brace-pos nil nil ppss))
      (setq last-ppss-pos brace-pos)
      (forward-char)
      (cond ((conshine-ignore brace-pos ppss brace-stxcode)
             nil)
            ((= 4 (logand #xFFFF brace-stxcode))
             (conshine-colourise brace-pos (1+ (nth 0 ppss)) t))
            (t
             (let ((matches-p (eq (cdr brace-stx) (char-after (nth 1 ppss)))))
               (conshine-colourise brace-pos (nth 0 ppss) matches-p)))))))