Easiest way to check if current line is "empty" (ignoring whitespace)?

Question

I just want to check if the current line is empty or not (if it contains only whitespace, then I still consider it empty).

Here is my initial version:

(defun strip-text-properties(txt)
  (set-text-properties 0 (length txt) nil txt)
  txt)

(defun is-current-line-empty ()
  (interactive)
  (setq c-line (thing-at-point 'line))
  (string-match "^\s*$" (strip-text-properties c-line)))

What is the easiest way to check if current line is empty?

In a lisp string, writing \s is equivalent to writing s. Perhaps you meant "^\\s*$". — YoungFrog, Sep 21 '15 at 15:23
As a general comment, elisp will make more sense once you start thinking in terms of actions on buffers, as opposed to (as one tends to do in other languages) doing things with strings. Isolating and extracting a string in order to perform some test is likely to (a) be inefficient, and (b) dramatically reduce the number of tools at your disposal. Elisp is really good at doing things directly on the contents of buffers. — phils, Sep 22 '15 at 00:10
@YoungFrog, also it should be \\s- instead of \\s. That hyphen is required in elisp regexp. — Kaushal Modi, Jul 26 '16 at 10:49

score 27 · Accepted Answer · edited Mar 14 '22 at 00:50

27

Would something like this be "easier"?

(defun current-line-empty-p ()
  (save-excursion
    (beginning-of-line)
    (looking-at-p "[[:blank:]]*$")))

edited Mar 14 '22 at 00:50

ideasman42

8,786
1
32
114

answered Sep 21 '15 at 13:42

François Févotte

6,007
1
25
38

Shouldn't space be blank? (to account for tabs) – ideasman42 Nov 15 '20 at 10:04
@ideasman42 space accounts for all whitespace, not just space characters. That said, blank might be better here because it only accounts for horizontal whitespace rather than all whitespace. Reference: https://www.gnu.org/software/emacs/manual/html_node/elisp/Char-Classes.html#Char-Classes – eeowaa Nov 17 '20 at 20:06
:space: uses the syntax table, where :blank: is simply space or tab, which seems more accurate. – ideasman42 Nov 17 '20 at 23:04

score 12 · Answer 2 · edited Sep 10 '19 at 20:17

12

A simple method, close to what you have:

(defun current-line-empty-p ()
  (string-match-p "\\`\\s-*$" (thing-at-point 'line)))

edited Sep 10 '19 at 20:17

Gilles 'SO- stop being evil'

22,318
4
56
92

answered Sep 22 '15 at 03:48

PythonNut

10,363
2
30
76

I like this solution because it does not modify match-data. – nispio Apr 25 '16 at 16:08
1

You need to have \\s- instead of \s. Have you tried that solution? – Kaushal Modi Jul 26 '16 at 10:51
Oddly, I do use it quite a bit. But I just wrote this off of memory. You are correct. – PythonNut Jul 26 '16 at 13:40
1

still missing the hyphen? :) – Kaushal Modi Jul 26 '16 at 13:53
1

It was early, and I hadn't completely woken up yet. – PythonNut Jul 27 '16 at 17:57
(thing-at-point 'line) seems to return nil in an empty buffer (or only whitespace in buffer) and then string-match-p returns an error as nil is not a string. So probably rather use (buffer-substring-no-properties (line-beginning-position) (line-end-position)). – Hubisan Jun 09 '23 at 10:01

score 5 · Answer 3 · answered Sep 21 '15 at 13:57

(defun blank-line-p (&optional pos)
  "Returns `t' if line (optionally, line at POS) is empty or
composed only of whitespace."
  (save-excursion
    (goto-char (or pos (point)))
    (beginning-of-line)
    (= (point-at-eol)
       (progn (skip-syntax-forward " ") (point)))))

score 3 · Answer 4 · answered Sep 22 '15 at 00:57

3

current-indentation gives you the column following leading blanks, which can be compared against the column at the end of line:

(defun blank-line-p ()
  (= (current-indentation)
     (- (line-end-position) (line-beginning-position))))

answered Sep 22 '15 at 00:57

npostavs

9,203
1
24
53

Am I missing something or this can be simplified to just (= (line-beginning-position) (line-end-position)) ? – Hi-Angel Oct 05 '23 at 08:00
Ah, nvm, I see, the answer is considering a line with whitespace to be empty as well. Nice answer! – Hi-Angel Oct 05 '23 at 08:10

score 2 · Answer 5 · edited Jan 10 '21 at 05:52

2

Here is another simple solution for it, taken from comment-dwim-2 package

(defun is-empty-line-p ()
  (string-match-p "^[[:blank:]]*$"
        (buffer-substring (line-beginning-position)
                          (line-end-position))))

edited Jan 10 '21 at 05:52

ideasman42

8,786
1
32
114

answered Sep 21 '15 at 19:36

Chillar Anand

4,102
1
24
52

score 1 · Answer 6 · answered Sep 21 '15 at 15:22

1

I suggest:

(defun blank-line-p ()
  (and (progn (skip-chars-backward " ") (bolp))
       (progn (skip-chars-forward " ") (eolp))))

(Note that the progns are in fact unnecessary because the skip functions never return nil). As Dan does in his answer, skip-syntax-* could also be used instead.

answered Sep 21 '15 at 15:22

YoungFrog

3,526
18
28

3

This does not identify a line containing only tabs as blank. skip-syntax-* is the right set of functions to use here. – Gilles 'SO- stop being evil' Sep 21 '15 at 21:48

score 1 · Answer 7 · answered Sep 10 '19 at 18:05

1

This is a modification of what PythonNut answered which did not work for me (why?):

(defun current-line-blank ()
  (= 0 (string-match-p "^\\s-*$" (thing-at-point 'line))))

string-match-p returned the index of the next line whenever the current line wasn't blank. So I checked that the return value is 0.

answered Sep 10 '19 at 18:05

Dario

83
1
5

The index of the next line? What do you mean exactly? (and welcome on emacs.SE!) – JeanPierre Sep 10 '19 at 18:41
@JeanPierre (thing-at-point 'line) includes the newline at the end of the line. If the current line is not blank, the regexp matches at that newline. The only time string-match-p returns nil here is on the last line of the buffer (and Dario, your version doesn't work on the last line if the buffer doesn't end with a newline). – Gilles 'SO- stop being evil' Sep 10 '19 at 20:12
A better fix would be to match the beginning of the string instead of matching the beginning of any line in the string. I've edited PythonNut's answer. – Gilles 'SO- stop being evil' Sep 10 '19 at 20:18

Easiest way to check if current line is "empty" (ignoring whitespace)?

7 Answers7

Linked