Shell Command with bash script and arguements

Question

I have a bash script which Sweaves .Rnw files into pdf's.

sweave_to_pdf ~/Foo.Rnw

I am wanting to write a emacs function to invoke this script on the current buffer. So far I have this:

(defun sweave_to_pdf ()
  "sweave_to_pdf function"
(interactive)
(shell-command
"~/Scripts/Shell/sweave_to_pdf.sh" (buffer-file-name (window-buffer (minibuffer-selected-window))))
)

It seems the file name and path of the buffer is not being passed to the shell script as a line argument. Any ideas how I could achieve this?

score 2 · Accepted Answer · answered Jul 22 '15 at 15:46

2

The invocation needs to be a single string as the second and third argument refer to the output and error buffer:

(defun sweave-to-pdf ()
  "sweave_to_pdf function"
  (interactive)
  (shell-command (format "%s %s" "~/Scripts/Shell/sweave_to_pdf.sh"
                         buffer-file-name)))

answered Jul 22 '15 at 15:46

wasamasa

22,178
1
66
99

I'd add some (shell-quote-argument) magic around buffer-file-name to avoid problems with spaces and such. – YoungFrog Jul 22 '15 at 15:48
Worked perfectly. – branch.lizard Jul 22 '15 at 15:54

score 2 · Answer 2 · answered Jun 29 '17 at 02:33

As YoungFrog mentions, you must quote the file name. Otherwise, the code fails if, for instance, the file name contains whitespaces.
You might explicitely check that the current buffer is visiting a file.

(defun sweave-to-pdf ()
  "Export a sweave file to pdf."
  (interactive)
  (let ((file buffer-file-name)
        (script "~/Scripts/Shell/sweave_to_pdf.sh"))
    (unless file (user-error "Buffer must be visiting a file"))
    (shell-command (format "%s %s" script (shell-quote-argument file)))))

Shell Command with bash script and arguements

2 Answers2