8

I'm trying to launch 3 tabs and run a script in each with AppleScript. So far I haven't been able to get this done. Currently I have:

tell application "Terminal"
    activate
    do script "ping google.com"
    tell application "System Events"
        keystroke "t" using {command down}
        do script "ping yahoo.com"
    end tell
    tell application "System Events"
        keystroke "t" using {command down}
        do script "ping msn.com"
    end tell
end tell

This will launch three tabs but the pings don't execute in the last two tabs.

I'm probably missing something basic here.

techraf
  • 3,958
Nick
  • 83

1 Answers1

17

  1. "System Events" doesn't understand what you want to do with do script, use the do script command outside of the tell application "System Events" block.

  2. You must specify a window or tab when using the do script command, otherwise a new window will open.

tell application "Terminal"
    activate
    do script "ping google.com" in front window
    my makeTab()
    do script "ping yahoo.com" in front window
    my makeTab()
    do script "ping msn.com" in front window
end tell

on makeTab()
    tell application "System Events" to keystroke "t" using {command down}
    delay 0.2
end makeTab
grg
  • 201,078
jackjr300
  • 2,582
  • I try to use in Mac M1. for Rosetta terminal,

    I made changes in tell application "Rosetta-Terminal"

    "Rosetta-Terminal got an error: "ping google.com" doesn’t understand the “do script” message." number -1708 from "ping google.com"

     – Solid Soft Jan 21 '22 at 10:40